(fwd from mbp@samba.org) CVS update: rsync
rsync at thewrittenword.com
rsync at thewrittenword.com
Thu Aug 9 01:23:17 EST 2001
On Thu, Aug 09, 2001 at 12:27:45AM +1000, Martin Pool wrote:
> On 8 Aug 2001, Albert Chin-A-Young <china at thewrittenword.com> wrote:
>
> > > Sorry, this is obviously wrong. Passing the wrong type will only give
> > > a warning on C, whereas I think it will give an error on C++.
>
> [BTW, I meant my blithely changing it to C was wrong; your suggestion
> was fine. :-]
>
> > I'm not having much luck here. Doing this in C is hard. BTW, did you
> > run into any problems by defining socklen_t to int as the default?
>
> Simply doing AC_CHECK_TYPE breaks on HP/UX 11.00 and 11.11 since it is
> not declared in sys/types.h. There may be a workaround for that -- I
> haven't looked closely at what autoconf produces for AC_CHECK_TYPE.
That's because you're using the "old" form of AC_CHECK_TYPE in
autoconf 2.13. You can get AC_CHECK_TYPE working with the version in
autoconf 2.52 (it allows you to set the #includes to search in).
> I'm not sure if that is the only problem: I don't think it's enough.
>
> The killer case is a machine which has 32-bit ints, 64-bit size_t (and
> parameter to sockaddr), and no sockaddr_t. I wouldn't be surprised if
> such a thing exists.
>
> By the way the Debian unstable autoconf2.13 / 2.50 transition fights
> with their libtool but I have filed a bug and expect it to be fixed
> soon.
>
> The propagation delay to test this on the samba build farm (10-60
> minutes) makes debugging it a bit tiresome. Still I guess it's the
> only realistic way to get access to a Cray.
>
> > I think redeclaring the prototype for getpeername seems to be an
> > interesting idea. I'm going to try this (this is kinda hairy though as
> > not all platforms have the first two parameters identical).
>
> I tried that. I haven't given up by I'm not using it at the moment.
> I think it failed because gcc declares other strange attributes like
> the C99 __restrict that cause the declaration to not match. It may be
> possible to fix.
Ok, the patch below tries this. I've tested on:
Solaris 2.5.2, 2.6, 7, 8/SPARC, HP-UX 10.20, 11.00,
Tru64 UNIX 4.0D, 5.0A, IRIX 6.2, 6.5, AIX 4.3.2
and it works ok.
This patch *requires* autoconf 2.52.
> tridge's suggestion was something like
>
> char lenarry[16], data[1];
>
> fd = make_connected_loopback_tcp_socket();
> bzero(lenarry, sizeof lenarry);
> getpeername(fd, &data, (void *) &lenarry);
>
> grovel through lenarry to work out how much of it was actually
> filled with a number.
>
> This is pretty gross because for every function that I can see the
> argument passed in has to be initialized beforehand, so we can't just
> fill it with 0xff.
Ick!
BTW, this patch also gets rid of getconf. Didn't we discuss this
earlier? I replaced it with AC_SYS_LARGEFILE which is included in
autoconf 2.52.
--
albert chin (china at thewrittenword.com)
-- snip snip
Index: aclocal.m4
===================================================================
RCS file: /cvsroot/rsync/aclocal.m4,v
retrieving revision 1.5
diff -u -3 -p -r1.5 aclocal.m4
--- aclocal.m4 8 Aug 2001 10:04:40 -0000 1.5
+++ aclocal.m4 8 Aug 2001 15:15:39 -0000
@@ -22,81 +22,6 @@ AC_DEFUN(AC_VALIDATE_CACHE_SYSTEM_TYPE,
ac_cv_target_system_type="$target"
])
-#serial 12
-
-dnl By default, many hosts won't let programs access large files;
-dnl one must use special compiler options to get large-file access to work.
-dnl For more details about this brain damage please see:
-dnl http://www.sas.com/standards/large.file/x_open.20Mar96.html
-
-dnl Written by Paul Eggert <eggert at twinsun.com>.
-
-dnl Internal subroutine of AC_SYS_LARGEFILE.
-dnl AC_SYS_LARGEFILE_TEST_INCLUDES
-AC_DEFUN(AC_SYS_LARGEFILE_TEST_INCLUDES,
- [[#include <sys/types.h>
- int a[(off_t) 9223372036854775807 == 9223372036854775807 ? 1 : -1];
- ]])
-
-dnl Internal subroutine of AC_SYS_LARGEFILE.
-dnl AC_SYS_LARGEFILE_MACRO_VALUE(C-MACRO, VALUE, CACHE-VAR, COMMENT, INCLUDES, FUNCTION-BODY)
-AC_DEFUN([AC_SYS_LARGEFILE_MACRO_VALUE],
- [AC_CACHE_CHECK([for $1 value needed for large files], $3,
- [$3=no
- AC_TRY_COMPILE(AC_SYS_LARGEFILE_TEST_INCLUDES
-$5
- ,
- [$6],
- ,
- [AC_TRY_COMPILE([#define $1 $2]
-AC_SYS_LARGEFILE_TEST_INCLUDES
-$5
- ,
- [$6],
- [$3=$2])])])
- if test "[$]$3" != no; then
- AC_DEFINE_UNQUOTED([$1], [$]$3, [$4])
- fi])
-
-AC_DEFUN([AC_SYS_LARGEFILE],
- [AC_ARG_ENABLE(largefile,
- [ --disable-largefile omit support for large files])
- if test "$enable_largefile" != no; then
-
- AC_CACHE_CHECK([for special C compiler options needed for large files],
- ac_cv_sys_largefile_CC,
- [ac_cv_sys_largefile_CC=no
- if test "$GCC" != yes; then
- # IRIX 6.2 and later do not support large files by default,
- # so use the C compiler's -n32 option if that helps.
- AC_TRY_COMPILE(AC_SYS_LARGEFILE_TEST_INCLUDES, , ,
- [ac_save_CC="$CC"
- CC="$CC -n32"
- AC_TRY_COMPILE(AC_SYS_LARGEFILE_TEST_INCLUDES, ,
- ac_cv_sys_largefile_CC=' -n32')
- CC="$ac_save_CC"])
- fi])
- if test "$ac_cv_sys_largefile_CC" != no; then
- CC="$CC$ac_cv_sys_largefile_CC"
- fi
-
- AC_SYS_LARGEFILE_MACRO_VALUE(_FILE_OFFSET_BITS, 64,
- ac_cv_sys_file_offset_bits,
- [Number of bits in a file offset, on hosts where this is settable.])
- AC_SYS_LARGEFILE_MACRO_VALUE(_LARGEFILE_SOURCE, 1,
- ac_cv_sys_largefile_source,
- [Define to make ftello visible on some hosts (e.g. HP-UX 10.20).],
- [#include <stdio.h>], [return !ftello;])
- AC_SYS_LARGEFILE_MACRO_VALUE(_LARGE_FILES, 1,
- ac_cv_sys_large_files,
- [Define for large files, on AIX-style hosts.])
- AC_SYS_LARGEFILE_MACRO_VALUE(_XOPEN_SOURCE, 500,
- ac_cv_sys_xopen_source,
- [Define to make ftello visible on some hosts (e.g. glibc 2.1.3).],
- [#include <stdio.h>], [return !ftello;])
- fi
- ])
-
dnl Check for socklen_t: historically on BSD it is an int, and in
dnl POSIX 1g it is a type of its own, but some platforms use different
dnl types for the argument to getsockopt, getpeername, etc. So we
@@ -108,50 +33,37 @@ dnl the moment.
AC_DEFUN([TYPE_SOCKLEN_T],
[
- AC_MSG_CHECKING([for socklen_t])
- AC_CACHE_VAL([lftp_cv_socklen_t],
- [
- lftp_cv_socklen_t=no
- AC_TRY_COMPILE([
- #include <sys/types.h>
- #include <sys/socket.h>
- ],
- [
- socklen_t len;
- getpeername(0,0,&len);
- ],
- [
- lftp_cv_socklen_t=yes
- ])
- ])
- AC_MSG_RESULT($lftp_cv_socklen_t)
- if test $lftp_cv_socklen_t = no; then
+ AC_CHECK_TYPE([socklen_t], ,[
AC_MSG_CHECKING([for socklen_t equivalent])
- AC_CACHE_VAL([lftp_cv_socklen_t_equiv],
+ AC_CACHE_VAL([rsync_cv_socklen_t_equiv],
[
- lftp_cv_socklen_t_equiv=int
- AC_LANG_SAVE
- for t in int size_t unsigned long "unsigned long"; do
- AC_TRY_COMPILE([
- #include <sys/types.h>
- #include <sys/socket.h>
- ],
- [
- $t len;
- getpeername(0,0,&len);
- ],
- [
- lftp_cv_socklen_t_equiv="$t"
- break
- ],
- [
- AC_MSG_ERROR([Cannot find a type to use in place of socklen_t])
- ])
+ # Systems have either "struct sockaddr *" or
+ # "void *" as the second argument to getpeername
+ rsync_cv_socklen_t_equiv=
+ for arg2 in "struct sockaddr" void; do
+ for t in int size_t unsigned long "unsigned long"; do
+ AC_TRY_COMPILE([
+ #include <sys/types.h>
+ #include <sys/socket.h>
+
+ int getpeername (int, $arg2 *, $t *);
+ ],[
+ $t len;
+ getpeername(0,0,&len);
+ ],[
+ rsync_cv_socklen_t_equiv="$t"
+ break
+ ])
+ done
done
+
+ if test "x$rsync_cv_socklen_t_equiv" = x; then
+ AC_MSG_ERROR([Cannot find a type to use in place of socklen_t])
+ fi
])
- AC_MSG_RESULT($lftp_cv_socklen_t_equiv)
- AC_DEFINE_UNQUOTED(socklen_t, $lftp_cv_socklen_t_equiv,
- [type to use in place of socklen_t if not defined])
- fi
+ AC_MSG_RESULT($rsync_cv_socklen_t_equiv)
+ AC_DEFINE_UNQUOTED(socklen_t, $rsync_cv_socklen_t_equiv,
+ [type to use in place of socklen_t if not defined])],
+ [#include <sys/types.h>
+#include <sys/socket.h>])
])
-
Index: configure.in
===================================================================
RCS file: /cvsroot/rsync/configure.in,v
retrieving revision 1.80
diff -u -3 -p -r1.80 configure.in
--- configure.in 8 Aug 2001 10:04:40 -0000 1.80
+++ configure.in 8 Aug 2001 15:15:39 -0000
@@ -28,13 +28,6 @@ fi
CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
-# look for getconf early as this affects just about everything
-AC_CHECK_PROG(HAVE_GETCONF, getconf, "yes", "no")
-if test $HAVE_GETCONF = "yes"; then
- CFLAGS=$CFLAGS" "`getconf LFS_CFLAGS 2> /dev/null`
- LDFLAGS=$LDFLAGS" "`getconf LFS_LDFLAGS 2> /dev/null`
-fi
-
AC_ARG_WITH(included-popt,
[ --with-included-popt use bundled popt library, not from system])
@@ -77,8 +70,7 @@ AC_TYPE_PID_T
AC_TYPE_GETGROUPS
AC_STRUCT_ST_RDEV
AC_CHECK_TYPE([ino_t], [unsigned])
-dnl TYPE_SOCKLEN_T
-AC_CHECK_TYPE([socklen_t], [size_t])
+TYPE_SOCKLEN_T
AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
More information about the rsync
mailing list